<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" 
	layout="vertical"
	width="700" height="450"
	creationComplete="openDatabase()">
 
	<mx:Script source="asSQL/sqlConnection.as" />
 
    <!--
		FORM INSERIMENTO NUOVI CLIENTI nel db
	-->
    <mx:HBox width="100%"  horizontalAlign="center">
	     <mx:Label text="Nome Cliente"/>
		 <mx:TextInput id="nomeTxt" width="100" text="Nome"/>
		 <mx:TextInput id="cognomeTxt" width="100" text="Cognome"/>
		 <mx:Button label="Inserisci" click="insertRecord()"/>
	</mx:HBox>
 
    <mx:HRule width="100%"/>
	<mx:Label text="Record Tabella Clienti"/>
 
	<!--
	DATAGRID con l'ELENCO CLIENTI inseriti nel db:
	I nomi delle colonne dovranno coincidere con quelli dei campi del db, 
	affinchè le colonne del datagrid siano popolate automaticamente
	-->
	<mx:DataGrid id="grid" width="100%" height="100%">
		<mx:columns>
		     <mx:DataGridColumn dataField="ID" />
		 	 <mx:DataGridColumn dataField="NOME_CLIENTE" />
		 	 <mx:DataGridColumn dataField="COGNOME_CLIENTE" />
		</mx:columns>
	</mx:DataGrid>
 
 
</mx:WindowedApplication>

import flash.filesystem.File;
import flash.events.SQLErrorEvent;
import flash.events.SQLEvent;
import flash.data.SQLConnection;
import flash.data.SQLStatement;
import flash.data.SQLResult;
import mx.controls.Alert; 
 
public var conn:SQLConnection;
 
 
private function openDatabase():void{
 
  	 // Creiamo una nuova connessione SQL
     conn = new SQLConnection(); 
     conn.addEventListener(SQLErrorEvent.ERROR, errorHandler);
 
	// Reference al file del database .db (sarà posizionato sul desktop) 
    var dbFile:File = File.desktopDirectory.resolvePath("Tutorial_UM_AIR_SQL.db"); 
 
 
    // ==> Se il file del DB esiste ed è quindi già stato creato:
    if(dbFile.exists) 
    {
 
       // Listener per l'APERTURA del database 
       conn.addEventListener(SQLEvent.OPEN, openHandler);
 
       // Apertura Database 
	   conn.open(dbFile);  
 
    } 
      else
      // ==> Se il file del DB ancora non esiste: 
    {
 
      // Listener per la CREAZIONE del database
      conn.addEventListener(SQLEvent.OPEN, createHandler);
 
      // Creazione Database, utilizzando nuovamente il metodo open(), 
// il quale crea automaticamente un nuovo db nel caso in cui 
// non trovasse il file all'url specificato
      conn.open(dbFile);
 
      // Creazione della Tabella "Clienti"
      createClientsTable();
 
    }
 
}
 
 
// Se l'apertura del db avviene con successo, verrà invocata la funzione  
// showAllRecords() e tutti i clienti presenti nel db saranno visualizzati nel datagrid 
private function openHandler(event:SQLEvent):void { 
	showAllRecords()
}
 
 
 
// Evento invocato dopo la creazione del db (solo al primo avvio dell'applicazione) 
private function createHandler(event:SQLEvent):void { 
    Alert.show("Il DataBase è stato creato", "createHandler");
}

private function createClientsTable():void{
 
    // Query per la creazione delle tabella:
    // @field	 ID 
    // @field	 NOME_CLIENTE 
    // @field	 COGNOME_CLIENTE
    // NOTA: i nomi dei campi della tabella dovranno necessariamente coincidere
    // con quelli utilizzati nel codice MXML nelle colonne del datagrid
 
    var sqlText:String = "CREATE TABLE Clienti(ID INTEGER PRIMARY KEY, " + 
                         					"NOME_CLIENTE TEXT," + 
                         					"COGNOME_CLIENTE TEXT)"
                         					;
 
 
    // Eseguiamo la query
    var createTableStatement:SQLStatement = new SQLStatement();
    createTableStatement.sqlConnection = conn;
    createTableStatement.addEventListener(SQLEvent.RESULT, createTableResult);
    createTableStatement.addEventListener(SQLErrorEvent.ERROR, errorHandler);
    createTableStatement.text = sqlText;
    createTableStatement.execute(); 
}
 
 
 
 
 
 
// Evento invocato dopo la creazione della Tabella
private function createTableResult(event:SQLEvent):void { 
   // Eventuali messaggi e operazioni da effettuare dopo 
   // la creazione della tabella
}

private function insertRecord():void
{
   // Query per l'inserimento di un nuovo utente.
   // Passiamo come parametri nomeCliente e cognomeCliente
   var sqlText:String = "INSERT INTO Clienti(NOME_CLIENTE, COGNOME_CLIENTE) " + 
                         "VALUES(:nomeCliente, :cognomeCliente)" ;
 
   var insertStatement:SQLStatement = new SQLStatement();
   insertStatement.sqlConnection = conn;
   insertStatement.addEventListener(SQLEvent.RESULT, insertResult);
   insertStatement.addEventListener(SQLErrorEvent.ERROR, errorHandler);
   insertStatement.text = sqlText;
 
   // Acquisiamo i valori da inserire nella query  dai campi di 
   // input del form, abbinandoli ai parametri passati nella query
   insertStatement.parameters[":nomeCliente"] = nomeTxt.text;
   insertStatement.parameters[":cognomeCliente"] = cognomeTxt.text;
 
   // Eseguiamo la query
   insertStatement.execute();
}
 
 
// Ad ogni INSERT invochiamo la funzione showAllRecords() per verificare 
// l'avvenuto inserimento, visualizzando nel datagrid tutti i clienti presenti nel db
private function insertResult(event:SQLEvent):void {
 
   // Eliminiamo il contenuti dai campi di input 
   nomeTxt.text = "";
   cognomeTxt.text = "";
 
   // Effettuiamo una query sul DB per recuperare i dati e popolare il DataGrid
   showAllRecords();
}

private function showAllRecords():void{
   var sqlText:String = "SELECT * FROM Clienti";
   var selectAllSQL:SQLStatement = new SQLStatement();
   selectAllSQL.sqlConnection = conn;
   selectAllSQL.addEventListener(SQLEvent.RESULT, selectAllRecordsResult);
   selectAllSQL.addEventListener(SQLErrorEvent.ERROR, errorHandler);
   selectAllSQL.text = sqlText;
   selectAllSQL.execute();
}
 
 
// Evento invocato dopo la query SELECT
private function selectAllRecordsResult(event:SQLEvent):void{
 
	// Popoliamo il datagrid con il risultato della SELECT
   var result:SQLResult = event.currentTarget.getResult();
   grid.dataProvider = result.data;
 
}

private function errorHandler(event:SQLErrorEvent):void { 
   var err:String = "ID Errore:" + event.error.errorID + "nDettagli:" +
                     event.error.message;
 
   Alert.show(err,"Errore"); 
}