<?xml version="1.0" encoding="utf-8" ?>
<data>
 
	<item>
		<title>WebSite</title>
		<link>http://www.fabiobiondi.com</link>		
	</item>
 
	<item>
		<title>My Blog</title>
		<link>http://www.fabiobiondi.com/blog</link>		
	</item>
 
	<item>
		<title>Google</title>
		<link>http://www.google.com</link>		
	</item>
 
</data>

package 
{
	import fl.controls.List;
	import fl.controls.Button;
	import fl.controls.TextArea;
	import fl.data.DataProvider;
	import fl.events.ListEvent;
	import flash.desktop.NativeApplication;
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.text.TextFormat;
	import flash.net.navigateToURL;
 
 
	public class XMLLoaderBase extends MovieClip
	{
		private var xmlData:XML;
		private var list:List;
		private var msgTxt:TextArea;
 
 
		public function XMLLoaderBase() 
		{
			uiCreation();
			loadXML("info.xml")
		}
 
 
		/**
		 * Create the UI.
		 * Remember to import all the component assets in your flash library
		 */
		private function uiCreation():void {
 
			var format:TextFormat = new TextFormat();
			format.size = 25;
 
			// Create the TextArea to display the xml content and urls
			msgTxt = new TextArea();
			msgTxt.move(5, 5)
			msgTxt.width = this.stage.stageWidth - 10;
			msgTxt.height = 300
			msgTxt.setStyle("textFormat",format) 
			addChild (msgTxt)
 
			// Create the links LIST Component
			list = new List();
			list.move (msgTxt.x , msgTxt.y + msgTxt.height + 5)
			list.width = msgTxt.width;
			list.height = msgTxt.height;
			list.addEventListener(ListEvent.ITEM_CLICK, onListClick)
			addChild(list)
 
			// Display the BUTTON "Visit URL"
			var button:Button = new Button();
			button.label = "Open URL";
			button.width = 150;
			button.height = 40;
			button.setStyle("textFormat",format) 
			button.x = list.x;
			button.y = list.y + list.height + 5;
			button.addEventListener(MouseEvent.CLICK, gotoURL)
			addChild(button)
 
 
		}
 
 
 
		/**
		 * Load the XML 
		 */
		private function loadXML(url:String):void
		{
			xmlData = new XML();
 
			var xmlLoader:URLLoader = new URLLoader();
			xmlLoader.addEventListener(Event.COMPLETE, onXMLLoaded)
			xmlLoader.load(new URLRequest(url)); 
 
		}
 
 
		/**
		 * XML data are successfully loaded
		 * @param	e
		 */
		private function onXMLLoaded(e:Event):void 
		{
			xmlData = XML(e.target.data )
 
			// Display all the xml content
			msgTxt.text = "Display all ITEMS:nn" 		+ xmlData.item + "n";
 
 
			// Create a list component from the XML content
			populateList();
		}
 
 
 
		/**
		 * Create a list to display nodes
		 */
		private function populateList():void {
 
 
			// List population
			var dp:Array = new Array();
 
			for (var i:int = 0; i < xmlData.item.length(); i++) 
			{
				var item:XML = xmlData.item[i];
 
				 dp.push( { label: item.title , 
							data: item.link } );	
 
			}
 
			list.dataProvider = new DataProvider(dp)
			list.selectedIndex = 0;
 
		}
 
 
		/**
		 * On List selection
		 * 
		 * @param	e
		 */
		private function onListClick(e:ListEvent):void 
		{
			var list:List = e.target as List;
			var item:Object = e.item;
 
			msgTxt.text = item.label + " - " + item.data;
 
		}
 
 
		/**
		 * Open the URL using the default Android browser
		 */ 
		private function gotoURL(e:Event):void 
		{
			navigateToURL(new URLRequest(list.selectedItem.data)); 
		}
	}
 
}